Circuit Model Description

This section explains the circuit descriptions for the ADS simulator.

Selecting Simulator Options

ADS simulation options are specified using the HPEESOFSIM_OPTIONS variable in the Setup DUT or System Variable tables. Enter the options in the value section of the variable exactly as they should appear in the ADS options command.

Entering Circuit Descriptions

The circuit description is entered into the IC-CAP Circuit Editor or the Test Circuit Editor. The circuit description includes the necessary definitions of devices, sources and components, as well as node connections and model descriptions. ADS accepts a netlist description that is different from SPICE and Saber simulators.

Parameter Table Generation

The circuit description is parsed by IC-CAP and specific model information (such as parameters and their corresponding values) as well as circuit component values are reflected in the Parameters table. Model parameters and component values specified in the circuit description entered in the Circuit Editor are saved in the Parameters table. Device parameters specified in the model call statement are saved in the DUT Parameters table—unless a Test Circuit is specified, in which case, parameter values specified in the test circuit description are saved in the DUT Parameters table.

By default, all parameter names will be converted to uppercase, since most extraction routines look for parameters named with all uppercase letters. Some extraction routines (e.g., Root models and EExxx models) require all lowercase letters. In these .mdl files, the variable HPEESOFSIM_USE_LOWER_CASE_PARAMS is declared to override the default behavior. If you want to write extraction routines using the native mixed case parameters, declare the variable HPEESOFSIM_USE_MIXED_CASE_PARAMS in your model file. For a description of these functions, see the System Variables.

Non-numeric Parameter Values

ADS allows non-numeric values for a number of parameters in predefined component definitions. One example is the BJT model parameter npn. This parameter can take on the value of yes if it is an nmos device. Alpha format parameters do not appear in the IC-CAP Parameters table but do appear in the simulation input decks.

Circuit descriptions must be entered with valid model and parameter names for the particular model being used.

Node Names

ADS accepts alphanumeric names as well as numbers to represent nodes. There is no limit on the number of characters allowed in a node name; however, delimiters or non-alphanumeric characters are not allowed. Also, a node name that begins with a digit must consist only of digits.

Numeric node names are discouraged as they will result in warnings during simulation that the results will not be displayed properly in ADS Data Display Server (DDS). However, these warnings are of no consequence to ICCap.

Comments

To indicate comments in an ADS input deck, start an input line with a semicolon (;). All text on the line following the semicolon will be ignored.

Device Model Descriptions

A device model is used to characterize a single ADS-defined element of any type. This specification requires a model definition that describes the device and an instance statement that calls the model definition.

The model description specifies the value of a device model that describes a particular element. When a parameter is not specified, the default value in the model is used. The general form of the model definition is:

 model MNAME TYPE PNAME1 = PVAL1 PNAME2 = PVAL2...

where

MNAME is the model name. (Regardless of the model name entered into the MNAME field of the ADS model definition statement, IC-CAP substitutes this field with the name of the Model as it is called in the Main window when the simulator input deck is built.)

TYPE is a valid ADS element type.

PNAMEs are parameter names available for the particular model type.

PVALs are the parameter values.

A backslash immediately followed by a return (no space between the backslash and the return) at the end of a line indicates that the statement is continued on the next line This continuation character is often used for easier readability when specifying the model description.

The general form of the instance statement that calls the device model is:

 TYPE :DNAME NNAME1 NNAME2...NNAMEN DPAR1 = DVAL1 
DPAR2 = DVAL2...DPARN = DVALN

where

TYPE is the instance type descriptor. This field can contain either the ADS instance type name or a user-supplied model or subcircuit name.

DNAME is the device name.

NNAMEs denote node names.

DPAR is a predefined DUT parameter name.

DVAL is the specified DUT parameter value. Refer to General Syntax for DUT parameter names available for each model.

Subcircuit Model Descriptions

A subcircuit definition represents a circuit that contains more than 1 device. The syntax for defining a subcircuit is identical to the syntax used for the ADS input language.

The general form of the subcircuit definition is:

 define SUBCKTNAME (NNAME1 NNAME2 ...NNAMEN)
parameters PAR1 = VAL1 PAR2 = VAL2 ...PARN = VALN
< body of subcircuit >
end SUBCKTNAME

where

SUBCKTNAME is the name of the subcircuit.

NNAMEs are the node names of the external nodes of the subcircuit. These external nodes are used to connect the subcircuit to another circuit.

PARs are the names of the parameters passed into the subcircuit. These parameters are optional in a subcircuit definition.

If parameters are specified, the assigned default values VAL are also optional. A parameter is assigned to this default value if the parameter is not specified in the subcircuit call.

The body of the subcircuit contains element statements. It can contain calls to other subcircuits but it cannot contain other subcircuit definitions.

The subcircuit definition is completed using the end SUBCKTNAME statement.

Calling a subcircuit definition allows you to insert all instances specified within the subcircuit into the circuit. The call requires a syntax identical to the syntax used in the ADS input language for any instance statement. The general form of the instance statement is:

 TYPE :INAME NNAME1 NNAME2....NNAMEN PAR1 = VAL1 PAR2 =
VAL2......PARN = VALN

(While the syntax shown here is correct, passed parameters are ignored by IC-CAP.)

where

TYPE is the instance type descriptor. If a subcircuit is being called, this field would contain the subcircuit name denoted by SUBCKTNAME.

INAME is the instantiated name of the subcircuit.

NNAMEs denote node names.

PARs are the subcircuit parameter names.

VALs are the specified subcircuit parameter values.

The following is an example of a complete subcircuit definition and subcircuit call.

Options ASCII_Rawfile=no UseNutmegFormat=yes

;Simulation Input File in hpeesofsim Input Deck Format

global RC1_r=4352

define hpsimopamp (2 3 4 6 7 )
; Internal OpAmp circuit
; using Boyle-Pederson Macro Model
; Input differential amplifier
NPN1:Q1  10 2 12 
NPN2:Q2  11 3 13 
model NPN1 BJT NPN=yes  \
Is = 8E-16  \
Bf = 52.81  
model NPN2 BJT NPN=yes  \
Is = 8.093E-16  \
Bf = 52.66  
R:RC1  7 10 R=RC1_r 
R:RC2  7 11 R=4352  
C:C1  10 11 C=4.529E-12  
R:RE1  12 14 R=2392  
R:RE2  13 14 R=2392  
R:RE  14 0 R=7.27E+06  
C:CE  14 0 C=7.5E-12  
; Power dissipation modeling resistor
R:RP  7 4 R=1.515E+04  
; 1st gain stage
 #uselib "ckt", "VCCS"
VCCS:GCM  14 0 0 15 G=1.152E-09  
VCCS:GA  10 11 15 0 G=0.0002298  
R:R2  15 0 R=1E+05  
; Compensation capacitor
C:C2  15 16 C=3E-11  
; 2nd gain stage
VCCS:GB  15 0 16 0 G=37.1  
R:RO2  16 0 R=489.2  
DMOD1:D1  16 17  
DMOD1:D2  17 16  
model DMOD1 Diode  \
Is = 3.822E-32  
R:RC  17 0 R=0.0001986  
VCCS:GC  6 0 0 17 G=5034  
; Output circuit
R:RO1  16 6 R=76.8  
DMOD2:D3  6 18  
DMOD2:D4  19 6  
model DMOD2 Diode  \
Is = 3.822E-32  
V_Source:VC  7 18 Vdc=1.604  
V_Source:VE  19 4 Vdc=3.104  
; Input diff amp bias source
I_Source:IEE  14 4 Idc=2.751E-05  
end hpsimopamp 

; Inverting Amplifier
define inv_amp (1 2 3 4 6 7 )
hpsimopamp:X1  2 3 4 6 7 
R:Rf  6 2 R=1E+04 
R:Rin  2 1 R=2000 
R:Rgnd  3 0 R=0.001 
end inv_amp 

inv_amp:XCKT n1 n2 n3 n4 n5 n6 
; START SOURCES
V_Source:V1GROUND n1 0 Vdc=0 Vac=1
V_Source:V7GROUND n6 0 Vdc=15
V_Source:V4GROUND n4 0 Vdc=-15
; END SOURCES
R:RO2 n2 0 R=100MEG
R:RO3 n3 0 R=100MEG
R:RO5 n5 0 R=100MEG
SweepPlan:swpfreq  Start = 1000 Stop = 1e+07 Dec = 3
AC:ac1 SweepPlan=swpfreq SweepVar="freq"