Special Considerations in Reading MOSFET SPICE Parameters

Special considerations must be taken into account in reading the parameters from a SPICE deck using geticcap.ddl, for two reasons. First, the extrinsic parasitic elements are not part of the MOSFET device or model card and must be added by the user. Second, only one device can be inserted into MDS at a time, but the scalable level 3 MOS model measures three devices. Explanations follow.

Adding Extrinsic Parasitic Elements

The extrinsic parasitic elements RG, LGG, LDD, and LSS that appear below the .SUBCKT line in the SPICE deck are not part of the MOSFET device or of the model card. (The intrinsic resistance elements RS and RD are part of both the device and the model card.) In order to include these elements as part of your MDS circuit, you need to add them as separate devices connected appropriately to the model element, using the extracted values given in the SPICE deck.

Setting the Geometry Parameters

In addition to the extrinsic parasitics listed above, certain device geometry parameters listed above the .MODEL line in the deck are not part of the model card. The geometry parameters L, W, AD, PD, AS, and PS must be entered for the specific device you intend to simulate. In a scalable MOSFET extraction, three devices are measured (large, short, and narrow). However, when you insert a device into MDS you will use only one of the devices measured in the extraction, or a device of a different size. Decide which device you will simulate and enter the corresponding geometry values for that device into the deck, using PERFORM > EDIT COMPONENT. (If you use the nonscalable MOS model with measurements of only one device, you will of course use the geometry parameters for that device.

These are the descriptions and default values for the geometry parameters:

Table 53 MOSFET Level 3 Geometry Parameters 

Parameter	Description	Default Value
L	Channel length in meters.	100 m
W	Channel width in meters.	100 m
AD	Area of drain diffusion in square meters.	0.0
AS	Area of source diffusion in square meters.	0.0
PD	Perimeter of drain junction in meters.	0.0
PS	Perimeter of source junction in meters.	0.0

AS, PD, and PS are used in the equations describing the junctions. The reverse current can be input either as IS (in A) or as JS in (A/m2). Whereas the first is an absolute value, the second is multiplied by AD and AS to give the reverse current of the drain and source junctions respectively. The same idea applies also to the zero-bias junction capacitances CBD and CBS (in F) on the one hand, and CJ (in F/m2) on the other. PD and PS multiply CJSW (in F/m) to obtain the perimeter capacitance.

Example SPICE Deck for MOSFET Level 3

The following is an example of an extracted SPICE deck for a high-frequency MOSFET level 3 model:

 .SUBCKT mos3_nhfs 1 2 3 4
RG 22 12 7.061
LGG 2 22 1.694E-10
LDD 1 11 3.538E-10
LSS 3 13 3.591E-11
M1 11 12 13 4
+ NMOS
+ L = 1.5E-06
+ W = 0.000352
+ AD = 1.936E-09
+ PD = 0.000176
+ AS = 1.936E-09
+ PS = 0.000176
.MODEL NMOS NMOS
+ LEVEL = 3
+ NSUB = 1.898E+16
+ UO = 1390
+ VTO = 0.5171
+ TPG = 1
+ NFS = 7.547E+12
+ TOX = 2.063E-08
+ NSS = 1E+10
+ VMAX = 1.546E+05
+ RS = 4.22
+ RD = 11.8
+ CBD = 5.518E-13
+ CJ = 0.000285
+ MJ = 0.2024
+ CJSW = 1.291E-15
+ MJSW = 0.1
+ IS = 1E-14
+ PB = 0.2972
+ FC = 0.5
+ XJ = 2.675E-07
+ LD = 1E-09
+ DELTA = 0.002
+ THETA = 1E-06
+ ETA = 0.2
+ KAPPA = 1E-06
+ CGSO = 2.113E-10
+ CGDO = 1.674E-10
+ CGBO = 0
+ XQC = 1
.ENDS